Libro: Basic Computer Games Microcomputer edition – Anno 1978 – Modifica del codice: Francesco Fiorentini
Quello che andiamo a presentarvi in questo articolo é il listato di un gioco estratto dal libro BASIC Computer Games (Microcomputer edition) a cura di David H. Ahl, pubblicato nel 1978 da Workman Publishing New York. Il libro é stato pubblicato anche come 101 BASIC Computer Games.
Il gameplay del gioco non é stato assolutamente toccato dalle modifiche, le quali si sono limitate ad un minimale adattamento alla modalitá Amstrad CPC ad 80 colonne, ma soprattutto all’aggiunta della visualizzazione delle fiches in mano al computer ed al giocatore in modo da rendere il gioco piú fluido.
Titolo: Game of Even Wins
Piattaforma: Amstrad CPC
Linguaggio: Locomotive Basic
Versione originale: Eric Peters
Pubblicazione: Basic Computer Games Microcomputer edition
Anno: 1978
Modifica del codice: Francesco Fiorentini
Anno: 2024
Note: Emulatore suggerito, WinAPE.
Istruzioni
All’inizio della partita, un numero casuale di fiches viene posizionato sul tabellone. il numero di fiches inizia sempre con un numero dispari. A ogni turno, un giocatore deve prendere una, due, tre o quattro fiches.
Vince il giocatore che finisce con un numero totale di fiches pari.
Il computer inizia conoscendo solo le regole del gioco. gradualmente impara a giocare bene. dovrebbe essere difficile battere il computer dopo venti partite consecutive.
Buon divertimento!
Qui di seguito trovate il codice da copiare sul vostro Amstrad CPC.
Potete copiare il listato ed incollarlo su un emulatore come WinAPE.
Attenzione – Ci siamo resi conto che nel listato i caratteri ‘>’ e ‘<‘ potrebbero venir sostituiti dai rispettivi encoding html ‘>’ e ‘<’. Nel caso, sostituite questi valori nel listato prima di copiarlo sull’emulatore.
Listato: Game of Even Wins – Amstrad CPC – Locomotive Basic
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
2 PRINT TAB(15);"CREATIVE COMPUTING MORRISTOWN, NEW JERSEY"
3 PRINT:PRINT
4 INPUT "DO YOU WANT INSTRUCTIONS (Y:YES OR N:NO)";A$:PRINT
5 IF A$="N" OR A$="n" THEN 20
6 PRINT "THE GAME IS PLAYED AS FOLLOWS:":PRINT
7 PRINT "AT THE BEGINNING OF THE GAME, A RANDOM NUMBER OF CHIPS ARE"
8 PRINT "PLACED ON THE BOARD. THE NUMBER OF CHIPS ALWAYS STARTS"
9 PRINT "AS AN ODD NUMBER. ON EACH TURN, A PLAYER MUST TAKE ONE,"
10 PRINT "TWO, THREE, OR FOUR CHIPS. THE WINNER IS THE PLAYER WHO"
11 PRINT "FINISHES WITH A TOTAL NUMBER OF CHIPS THAT IS EVEN."
12 PRINT "THE COMPUTER STARTS OUT KNOWING ONLY THE RULES OF THE"
13 PRINT "GAME. IT GRADUALLY LEARNS TO PLAY WELL. IT SHOULD BE"
14 PRINT "DIFFICULT TO BEAT THE COMPUTER AFTER TWENTY GAMES IN A ROW."
15 PRINT "TRY IT!!!!": PRINT
16 PRINT "TO QUIT AT ANY TIME, TYPE A '0' AS YOUR MOVE.": PRINT
20 DIM R(1,5)
25 L=0: B=0
30 FOR I=0 TO 5
40 R(1,I)=4
50 R(0,I)=4
60 NEXT I
70 A=0: B=0
90 P=INT((13*RND(1)+9)/2)*2+1
100 IF P=1 THEN 530
110 PRINT "THERE ARE";P;"CHIPS ON THE BOARD."
120 E1=E
130 L1=L
140 E=(A/2-INT(A/2))*2
150 L=INT((P/6-INT(P/6))*6+.5)
160 IF R(E,L)>=P THEN 320
170 M=R(E,L)
180 IF M<=0 THEN 370
190 P=P-M
200 IF M=1 THEN 510
210 PRINT "COMPUTER TAKES";M;"CHIPS LEAVING";P;"... YOUR MOVE";
220 B=B+M
221 PRINT:PRINT "--> CPU: ";B
222 PRINT "--> YOU: ";A
230 INPUT M
240 M=INT(M)
250 IF M<1 THEN 450
260 IF M>4 THEN 460
270 IF M>P THEN 460
280 IF M=P THEN 360
290 P=P-M
300 A=A+M
301 PRINT:PRINT "--> CPU: ";B
302 PRINT "--> YOU: ";A
310 GOTO 100
320 IF P=1 THEN 550
330 PRINT "COMPUTER TAKES";P;"CHIPS."
340 R(E,L)=P
350 B=B+P
360 IF B/2=INT(B/2) THEN 420
370 PRINT "GAME OVER... YOU WIN!!!": PRINT
390 IF R(E,L)=1 THEN 480
400 R(E,L)=R(E,L)-1
410 GOTO 70
420 PRINT "GAME OVER... CPU WINS!!!": PRINT
430 GOTO 70
450 IF M=0 THEN 570
460 PRINT M;"IS AN ILLEGAL MOVE... YOUR MOVE";
470 GOTO 230
480 IF R(E1,L1)=1 THEN 70
490 R(E1,L1)=R(E1,L1)-1
500 GOTO 70
510 PRINT "COMPUTER TAKES 1 CHIP LEAVING";P;"... YOUR MOVE";
520 GOTO 220
530 PRINT "THERE IS 1 CHIP ON THE BOARD."
540 GOTO 120
550 PRINT "COMPUTER TAKES 1 CHIP."
560 GOTO 340
570 END
