Rivista: A.N.A.L.O.G. – Anno: 1981 – Trascrizione: Fiorentini Francesco
Era da quasi un anno, dal listato di Sub Hunt, che non presentavamo un gioco per Atari 8bit.
Blocked é un gioco che si ispira profondamente a Light Cycle, il gioco della corsa delle moto che abbiamo potuto ammirare nel film TRON.
Le regole del gioco sono abbastanza semplici:
Obiettivo: Il giocatore deve sopravvivere più a lungo possibile evitando collisioni con le moto avversarie e le tracce lasciate.
Movimento: Le moto si muovono in avanti costantemente e non possono fermarsi. I giocatori possono solo girare a destra o a sinistra a angoli retti.
Trail luminoso: Ogni moto lascia dietro di sé una traccia luminosa che diventa solida e letale se attraversata da un’altra moto o se ne viene circondata.
Collisioni: Se una moto collide con un muro, con un’altra moto o con una traccia luminosa, il giocatore perde e viene eliminato dalla partita.
Strategia: La chiave per vincere è pianificare i movimenti in anticipo per tagliare il percorso degli avversari e rendere le loro mosse più difficili senza mettere a rischio la propria sopravvivenza.
Per iniziare, inserire un joystick nell’alloggiamento del paddle n. 1 e un altro stick nell’alloggiamento del paddle n. 2. Questi controlleranno rispettivamente i cursori a sinistra e a destra.
Potrete anche selezionare una delle cinque velocità, utilizzando lo stick a sinistra. La velocità più elevata richiede reazioni brusche per sopravvivere, mentre le velocità più basse incoraggiano una battaglia strategica.
Questo listato é stato pubblicato sulla rivista A.N.A.L.O.G. di Gennaio/Febbraio 1981, rivista edita da MICHAEL J. DESCHENES LEE PAPPAS.
Titolo: Blocked
Piattaforma: Atari 8bit
Linguaggio: Basic
Versione originale: David Bohlke
Pubblicazione: A.N.A.L.O.G.
Numero: 1 – Gennaio/Febbraio
Anno: 1981
Trascrizione: Francesco Fiorentini
Anno: 2024
Download: N/A
Note: Versione funzionante su tutte le macchine Atari 8bit.
Istruzioni
Inserire un joystick nell’alloggiamento del paddle n. 1 e un altro stick nell’alloggiamento del paddle n. 2.
Questi controlleranno rispettivamente i cursori a sinistra e a destra.
Potrete anche selezionare una delle cinque velocità, utilizzando lo stick a sinistra. La velocità più elevata richiede reazioni brusche per sopravvivere, mentre le velocità più basse incoraggiano una battaglia strategica.
.
Qui di seguito trovate il codice da copiare sul vostro computer Atari ad 8 bit.
Il codice é pronto per essere copiato su un emulatore, consigliamo Altirra.
Di seguito riportiamo le istruzioni per copiare il listato sull’emulatore Altirra ed eseguire il gioco:
– lanciare l’emulatore Altirra
– avviare il Basic: File -> Boot Image... e selezionare ATARIBAS.ROM (se non l’avete potete cercarla qui)
– copiate il codice sotto riportato
– incollatelo nell’emulatore tramite la funzione: View -> Paste Text
– per velocizzare l’operazione di copia del codice potete usare la funzione: System -> Warp Speed
– terminata l’operazione di copia (disattivate il Warp nel caso, System -> Warp Speed)
– digitare RUN
Buon divertimento!
Attenzione – Ci siamo resi conto che nel listato i caratteri ‘>’ e ‘<‘ potrebbero venir sostituiti dai rispettivi encoding html ‘>’ e ‘<’. Nel caso, sostituite questi valori nel listato prima di copiarlo sull’emulatore.
Listato: Blocked – Atari 8bit – Basic
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
4 GOTO 30
5 RETURN
6 RETURN
7 D=1
9 RETURN
10 RETURN
11 D=3:RETURN
13 D=2:RETURN
14 D=4:RETURN
15 RETURN
21 X=X+1:RETURN
22 Y=Y+1:RETURN
23 X=X-1:RETURN
24 Y=Y-1:RETURN
30 DIM A$(7):NG=0
40 GRAPHICS 1+16
41 SETCOLOR 0,15,10
42 SETCOLOR 1,12,9:SETCOLOR 2,8,9
43 POSITION 0,0:PRINT #6;LS;
44 POSITION 17,0:PRINT #6;RS;
45 POSITION 7,0:PRINT #6;"SCORE";
52 COLOR 131:PLOT 0,1:DRAWTO 19,1:DRAWTO 19,22
54 DRAWTO 0,22:DRAWTO 0,1:S=0
60 L1=2:L2=INT(RND(0)*16)+3:LD=1
65 R1=17:R2=INT(RND(0)*16)+3:RD=3
70 IF (LS>300) OR (RS>300) THEN 81
72 IF NG<>0 THEN 200
81 NG=1:LS=0:RS=0:SOUND 0,0,0,0
83 POSITION 6,5:PRINT #6;"BLOCKED"
84 POSITION 2,9:PRINT #6;"Press left stick"
85 POSITION 2,11:PRINT #6;"to select speed, "
86 POSITION 2,13:PRINT #6;"THEN PRESS FIRE";
90 T=1
91 POSITION 6,17:PRINT #6;"SPEED ";T;:FOR I=1 TO 100:NEXT I
92 IF STICK(0)<>15 THEN T=T+1:IF T>5 THEN T=1
96 IF STRIG(0)=0 THEN T=T*10:GOTO 40
98 SETCOLOR 3,RND(0)*15,RND(0)*10:SOUND 0,RND(0)*15,10,5:GOTO 91
200 COLOR 11:PLOT L1,L2
205 P=STICK(0):D=LD:GOSUB P:LD=D
210 X=L1:Y=L2:GOSUB D+20
220 L1=X:L2=Y:LOCATE L1,L2,P:IF P<>32 THEN 600
230 COLOR 10:PLOT L1,L2:SOUND 0,LD*10+50,10,7:FOR I=1 TO T:NEXT I:S=S+1
400 COLOR 171:PLOT R1,R2
405 P=STICK(1):D=RD:GOSUB P:RD=D
410 X=R1:Y=R2:GOSUB D+20
420 R1=X:R2=Y:LOCATE R1,R2,P:IF P<>32 THEN 700
430 COLOR 170:PLOT R1,R2:SOUND 0,RD*10+100,10,7:FOR I=1 TO T:NEXT I:S=S+1
490 GOTO 200
600 C=1:RS=RS+S:A$=" right":GOSUB 900
610 GOTO 40
700 C=2:LS=LS+S:A$=" left":GOSUB 900
710 GOTO 40
900 POSITION 0,23:PRINT #6;A$;" wins ";S;" pts";
910 FOR I=1 TO 10
912 SETCOLOR C,RND(1)*15,RND(1)*15
915 FOR J=1 TO 10
930 SOUND 0,RND(1)*200,12,10:NEXT J
940 NEXT I:RETURN
