Hangman – Commodore 128 – Basic V 7.0

Libro: 35 Amazing Games For Your COMMODORE 128 – Anno: 1986 – Trascrizione: Carlos J Vazquez II

Il Commodore 128 torna alla grande su RetroLiPS con una serie di interessanti recuperi frutto del lavoro di Carlos J Vazquez II che ha cominciato a preservare e conservare i listati presenti sul libro 35 Amazing Games For Your COMMODORE 128.

Si tratta di 35 giochi completi dotati di colori, grafica, suoni, intermezzi musicali, istruzioni per i giocatori e punteggio. Presentano tutte le capacità del Commodore 128 in modalità 128. Oltre all’elenco dei programmi, ogni gioco contiene suggerimenti per possibili variazioni. Per prima cosa inserite il gioco completo e funzionante. Provatelo così com’è. Poi, se lo desiderate, modificatelo.

Hangman: affinate le vostre abilità con le parole giocando a questo classico gioco con il computer. Il computer penserà a una parola. Voi dovrete indovinarla, lettera per lettera. Una lettera corretta verrà inserita nello spazio appropriato. Ogni lettera sbagliata aggiungerá un pezzo all’impiccato. Sono consentiti 12 errori prima di essere completamente impiccati. Quando l’impiccato è completo, viene visualizzata l’intera parola. Il computer fornisce 10 parole. Il punteggio si basa sulla lunghezza delle parole identificate correttamente e sul numero di lettere mancate.

Una caratteristica speciale è la visualizzazione dell’alfabeto nella parte superiore dello schermo. Ogni volta che si sceglie una lettera, questa viene evidenziata e bloccata, in modo da non poterla più utilizzare. I fan della musica dei cowboy riconosceranno il tema musicale The Streets of Laredo.

Il libro 35 Amazing Games For Your COMMODORE 128 puó essere recuperato qui: https://archive.org/details/35_Amazing_Games_for_the_Commodore_128_1984_HPBooks_Inc/mode/2up

Titolo: Hangman
Piattaforma: Commodore 128
Linguaggio: Basic V 7.0
Versione originale: John Mihalik
Pubblicazione: 35 Amazing Games For Your COMMODORE 128
Anno: 1986
Trascrizione: Carlos J Vazquez II
Anno: 2024
Download: N/A
Note: N/A

Istruzioni
Il computer penserá 10 parole ed il tuo compito é quello di scoprire quali sono indovinando tutte le lettere che le compongono.
12 Errori faranno apparire l’impiccato.
Le lettere dell’alfabeto verranno mostrate in cima alla schermo per ricordarti le lettere che sono giá state scelte.

Come sempre, qui di seguito trovate il codice ottimizzato per essere copiato direttamente su CBM prg Studio.

Attenzione – Ci siamo resi conto che nel listato i caratteri ‘>’ e ‘<‘ potrebbero venir sostituiti dai rispettivi encoding html ‘&gt’ e ‘&lt’. Nel caso, sostituite questi valori nel listato prima di copiarlo sull’emulatore.

Listato: Hangman – Commodore 128 – Basic V 7.0

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
10 rem hangman

20 scnclr

30 let x=0

40 let x=x+1:if x<2 then gosub 60

50 goto 140

60 tempo 12

70 play "v1o4t5u8xo":rem v1=guitar

80 a$="v1o4qc.qco3i$bqa$bo4qco3$b.qaigqfqcqc"

90 b$="v1o3hfififqgqaq$bqaqgqfqgqrqc"

100 c$="v1o4.qco3i$bqaq$bo4qco3q$b.qaigqgqeqc"

110 d$="v1o3hfififqgqaq$bqaqgf.f"

120 play a$:play b$:play c$:play d$

130 return

140 color0,7:color4,13:printtab(5)"{clear}{white}{reverse on}hangman "

150 print"{down}the computer will think of 10 words"

160 print"and you will try to guess them by":print"guessing all their letters."

170 print"{down}twelve wrong guesses build the hangman."

180 print"the alphabet will appear at the top of"

190 print"the screen to remind you what you have":print"already picked."

200 print"{down}hit any key to continue.":getkeyq$

210 dim w$(80),a(26),z(80):z(0)=80

220 forx=1to80:readw$(x):next

230 forx=1to80:z(x)=x:next:forx=0to9

240 r=int(rnd(1)*z(0)+1):w(x)=z(r)

250 z(r)=z(z(0)):z(0)=z(0)-1:next

260 forpl=0to9:gosub680

270 char1,1,20,"word #"+str$(pl+1)

280 forx=1 to len(w$(w(pl)))

290 char1,10+2*x,20,"-":next

300 char1,1,22,"pick a letter by hitting the key"

310 getkeyq$:ifq$<"a"orq$>"z"then310

320 l=asc(q$)-64:ifa(l)then310

330 char1,1,22,"{space*28}"

340 a(l)=1:char1,6+l,1,q$,1

350 p=instr(w$(w(pl)),q$):ifp=0thene=e+1:goto400

360 forx=1tolen(w$(w(pl)))

370 ifmid$(w$(w(pl)),x,1)=q$thenchar1,10+2*x,20,q$:cl=cl+1

380 next:ifcl<len(w$(w(pl)))then300

390 char1,1,21,"**success**":cw=cw+1:goto440

400 on e gosub720,790,850,870,900,920,940,960,980,1010,1040,1070

410 ife<12then300

420 char1,1,21,"sorry, the word was "+w$(w(pl))

430 gosub 60

440 char1,1,22,"hit any key for next word"

450 getkeyq$:scnclr:e=0:cl=0 

460 forx=1to26:a(x)=0:next:nextpl

470 graphic0:print"{clear}out of ten words, you guessed"cw:print"of them correctly"

480 print"{down}play again (y/n)?"

490 getkeyq$:ifq$="y"thenrun:elseifq$<>"n"then490

500 end

510 data the,and,that,for,with

520 data was,his,not,but,have

530 data you,which,are,her,had

540 data from,this,they,their,she

550 data has,were,been,him,one

560 data so,will,there,who,when

570 data what,your,more,would,them

580 data some,than,may,upon,its

590 data out,into,our,these,man

600 data like,shall,great,now,such

610 data should,other,only,any,then

620 data about,those,can,made,well

630 data old,must,said,time,even

640 data new,could,very,much,own

650 data most,might,first,after,yet

660 data two,end,easy,fly,begin

670 rem set  up screen

680 graphic1,1:color0,7:color1,2:color4,13

690 forx=65to90:char1,x-58,1,chr$(x):next

700 return

710 rem gallows

720 box1,149,27,187,32,0,1

730 box1,187,32,182,142,0,1

740 forx=0to10step5

750 box1,122-x,142+x,192+x,147+x,0,1

760 next

770 draw1,151,32 to 151,37:return

780 rem head

790 circle1,152,47,15,10

800 circle1,152,48,2,2:box1,149,52,155,54

810 paint1,145,47

820 char1,18,5,"--",1

830 return

840 rem neck

850 box1,150,57,154,62,0,1:return

860 rem body

870 circle1,152,85,10,23:paint1,152,85

880 return

890 rem r arm

900 box1,141,65,137,94,20,1:return

910 rem l arm

920 box1,163,65,167,94,340,1:return

930 rem r leg

940 box1,145,97,140,132,10,1:return

950 rem l leg

960 box1,159,97,163,132,350,1:return

970 rem r hand

980 circle1,133,98,3,3:paint1,133,98

990 return

1000 rem l hand

1010 circle1,171,98,3,3:paint1,171,98

1020 return

1030 rem r foot

1040 circle1, 137,136,4,4:paint1,137,136

1050 return

1060 rem l foot

1070 circle1,167,136,4,4:paint1,167,136

1080 return